Index: ossp-pkg/lmtp2nntp/Makefile.in
RCS File: /v/ossp/cvs/ossp-pkg/lmtp2nntp/Makefile.in,v
rcsdiff -q -kk '-r1.2' '-r1.3' -u '/v/ossp/cvs/ossp-pkg/lmtp2nntp/Makefile.in,v' 2>/dev/null
--- Makefile.in	2001/08/20 10:33:22	1.2
+++ Makefile.in	2001/08/20 10:45:44	1.3
@@ -1,8 +1,6 @@
 
 @SET_MAKE@
 
-ROOT    = /cw
-
 DESTDIR     =
 prefix      = @prefix@
 exec_prefix = @exec_prefix@
@@ -12,10 +10,9 @@
 mandir      = @mandir@
 
 CC      = @CC@
-CFLAGS  = @CFLAGS@ $(WFLAGS) `$(ROOT)/bin/str-config --cflags`
-WFLAGS  = -pedantic-errors -Wall -Wshadow -Wpointer-arith -Wcast-align -Winline -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Wno-long-long
-LDFLAGS = @LDFLAGS@ `$(ROOT)/bin/str-config --ldflags`
-LIBS    = @LIBS@ `$(ROOT)/bin/str-config --libs`
+CFLAGS  = @CFLAGS@
+LDFLAGS = @LDFLAGS@
+LIBS    = @LIBS@
 
 SHTOOL  = ./shtool
 POD2MAN = pod2man
Index: ossp-pkg/lmtp2nntp/aclocal.m4
RCS File: /v/ossp/cvs/ossp-pkg/lmtp2nntp/aclocal.m4,v
co -q -kk -p'1.1' '/v/ossp/cvs/ossp-pkg/lmtp2nntp/aclocal.m4,v' | diff -u /dev/null - -L'ossp-pkg/lmtp2nntp/aclocal.m4' 2>/dev/null
--- ossp-pkg/lmtp2nntp/aclocal.m4
+++ -	2024-05-05 07:00:23.106980591 +0200
@@ -0,0 +1,284 @@
+
+dnl ##
+dnl ##  Support for Platform IDs
+dnl ##
+dnl ##  configure.in:
+dnl ##    AC_PLATFORM(<variable>)
+dnl ##
+
+AC_DEFUN(AC_PLATFORM,[
+if test ".$host" != .NONE && test ".$host" != .; then
+    $1="$host"
+else
+    $1=`${CONFIG_SHELL-/bin/sh} $srcdir/config.guess`
+fi
+$1=`${CONFIG_SHELL-/bin/sh} $srcdir/config.sub $$1` || exit 1
+AC_SUBST($1)
+if test ".$enable_subdir" != .yes; then
+    echo "Platform: ${TB}${$1}${TN}"
+fi
+])dnl
+
+dnl ##
+dnl ##  Support for Configuration Headers
+dnl ##
+dnl ##  configure.in:
+dnl ##    AC_HEADLINE(<short-name>, <long-name>, 
+dnl ##                <vers-var>, <vers-file>, 
+dnl ##                <copyright>)
+dnl ##
+
+AC_DEFUN(AC_HEADLINE,[dnl
+AC_DIVERT_PUSH(NOTICE)dnl
+#   configuration header
+if test ".`echo dummy [$]@ | grep help`" = .; then
+    #   bootstrapping shtool
+    ac_prog=[$]0
+changequote(, )dnl
+    ac_srcdir=`echo $ac_prog | sed -e 's%/[^/][^/]*$%%' -e 's%\([^/]\)/*$%\1%'`
+changequote([, ])dnl
+    test ".$ac_srcdir" = ".$ac_prog" && ac_srcdir=.
+    ac_shtool="$ac_srcdir/shtool"
+
+    #   find out terminal sequences
+    TB=`$ac_shtool echo -n -e %B 2>/dev/null`
+    TN=`$ac_shtool echo -n -e %b 2>/dev/null`
+
+    #   find out package version
+    $3_STR="`$ac_shtool version -l c -d long $ac_srcdir/$4`"
+    AC_SUBST($3_STR)
+ 
+    #   friendly header ;)
+    echo "Configuring ${TB}$1${TN} ($2), Version ${TB}${$3_STR}${TN}"
+    echo "$5"
+
+    #   additionally find out hex version
+    $3_HEX="`$ac_shtool version -l c -d hex $ac_srcdir/$4`"
+    AC_SUBST($3_HEX)
+fi
+AC_DIVERT_POP()
+])dnl
+
+dnl ##
+dnl ##  Check whether compiler option works
+dnl ##
+dnl ##  configure.in:
+dnl ##    AC_COMPILER_OPTION(<name>, <display>, <option>,
+dnl ##                       <action-success>, <action-failure>)
+dnl ##
+
+AC_DEFUN(AC_COMPILER_OPTION,[dnl
+AC_MSG_CHECKING(whether compiler option(s) $2 work)
+AC_CACHE_VAL(ac_cv_compiler_option_$1,[
+SAVE_CFLAGS="$CFLAGS"
+CFLAGS="$CFLAGS $3"
+AC_TRY_COMPILE([],[], ac_cv_compiler_option_$1=yes, ac_cv_compiler_option_$1=no)
+CFLAGS="$SAVE_CFLAGS"
+])dnl
+if test ".$ac_cv_compiler_option_$1" = .yes; then
+    ifelse([$4], , :, [$4])
+else
+    ifelse([$5], , :, [$5])
+fi
+AC_MSG_RESULT([$ac_cv_compiler_option_$1])
+])dnl
+
+dnl ##
+dnl ##  Debugging Support
+dnl ##
+dnl ##  configure.in:
+dnl ##    AC_CHECK_DEBUGGING
+dnl ##
+
+AC_DEFUN(AC_CHECK_DEBUGGING,[dnl
+AC_ARG_ENABLE(debug,dnl
+[  --enable-debug          build for debugging (default=no)],
+[dnl
+if test ".$ac_cv_prog_gcc" = ".yes"; then
+    case "$CFLAGS" in
+        *-O* ) ;;
+           * ) CFLAGS="$CFLAGS -O2" ;;
+    esac
+    case "$CFLAGS" in
+        *-g* ) ;;
+           * ) CFLAGS="$CFLAGS -g" ;;
+    esac
+    case "$CFLAGS" in
+        *-pipe* ) ;;
+              * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
+    esac
+    AC_COMPILER_OPTION(ggdb3, -ggdb3, -ggdb3, CFLAGS="$CFLAGS -ggdb3")
+    CFLAGS="$CFLAGS -pedantic"
+    CFLAGS="$CFLAGS -Wall"
+    WMORE="-Wshadow -Wpointer-arith -Wcast-align -Winline"
+    WMORE="$WMORE -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
+    AC_COMPILER_OPTION(wmore, -W<xxx>, $WMORE, CFLAGS="$CFLAGS $WMORE")
+    AC_COMPILER_OPTION(wnolonglong, -Wno-long-long, -Wno-long-long, CFLAGS="$CFLAGS -Wno-long-long")
+else
+    case "$CFLAGS" in
+        *-g* ) ;;
+           * ) CFLAGS="$CFLAGS -g" ;;
+    esac
+fi
+msg="enabled"
+dnl AC_DEFINE(DEBUG)
+],[
+if test ".$ac_cv_prog_gcc" = ".yes"; then
+case "$CFLAGS" in
+    *-pipe* ) ;;
+          * ) AC_COMPILER_OPTION(pipe, -pipe, -pipe, CFLAGS="$CFLAGS -pipe") ;;
+esac
+fi
+case "$CFLAGS" in
+    *-g* ) CFLAGS=`echo "$CFLAGS" |\
+                   sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
+esac
+case "$CXXFLAGS" in
+    *-g* ) CXXFLAGS=`echo "$CXXFLAGS" |\
+                     sed -e 's/ -g / /g' -e 's/ -g$//' -e 's/^-g //g' -e 's/^-g$//'` ;;
+esac
+msg=disabled
+])dnl
+AC_MSG_CHECKING(for compilation debug mode)
+AC_MSG_RESULT([$msg])
+if test ".$msg" = .enabled; then
+    enable_shared=no
+fi
+])
+
+define(AC_IFALLYES,[dnl
+ac_rc=yes
+for ac_spec in $1; do
+    ac_type=`echo "$ac_spec" | sed -e 's/:.*$//'`
+    ac_item=`echo "$ac_spec" | sed -e 's/^.*://'`
+    case $ac_type in
+        header [)]
+            ac_item=`echo "$ac_item" | sed 'y%./+-%__p_%'`
+            ac_var="ac_cv_header_$ac_item"
+            ;;
+        file [)]
+            ac_item=`echo "$ac_item" | sed 'y%./+-%__p_%'`
+            ac_var="ac_cv_file_$ac_item"
+            ;;
+        func    [)] ac_var="ac_cv_func_$ac_item"   ;;
+        lib     [)] ac_var="ac_cv_lib_$ac_item"    ;;
+        define  [)] ac_var="ac_cv_define_$ac_item" ;;
+        typedef [)] ac_var="ac_cv_typedef_$ac_item" ;;
+        custom  [)] ac_var="$ac_item" ;;
+    esac
+    eval "ac_val=\$$ac_var"
+    if test ".$ac_val" != .yes; then
+        ac_rc=no
+        break
+    fi
+done
+if test ".$ac_rc" = .yes; then
+    :
+    $2
+else
+    :
+    $3
+fi
+])
+
+
+dnl ##
+dnl ##  Check for an external/extension library.
+dnl ##  - is aware of <libname>-config style scripts
+dnl ##  - searches under standard paths include, lib, etc.
+dnl ##  - searches under subareas like .libs, etc.
+dnl ##
+dnl ##  configure.in:
+dnl ##      AC_CHECK_EXTLIB(<realname>, <libname>, <func>, <header>,
+dnl ##                      [<success-action> [, <fail-action>]])
+dnl ##  Makefile.in:
+dnl ##      CFLAGS  = @CFLAGS@
+dnl ##      LDFLAGS = @LDFLAGS@
+dnl ##      LIBS    = @LIBS@
+dnl ##  shell:
+dnl ##      $ ./configure --with-<libname>[=DIR]
+dnl ##
+
+AC_DEFUN(AC_CHECK_EXTLIB,[dnl
+AC_ARG_WITH($2,dnl
+[  --with-]substr([$2[[=DIR]]                 ], 0, 19)[build against $1 library (default=no)],
+    if test ".$with_$2" = .yes; then
+        #   via config script
+        $2_version=`($2-config --version) 2>/dev/null`
+        if test ".$$2_version" != .; then
+            CPPFLAGS="$CPPFLAGS `$2-config --cflags`"
+            CFLAGS="$CFLAGS `$2-config --cflags`"
+            LDFLAGS="$LDFLAGS `$2-config --ldflags`"
+        fi
+    else
+        if test -d "$with_$2"; then
+            found=0
+            #   via config script
+            for dir in $with_$2/bin $with_$2; do
+                if test -f "$dir/$2-config"; then
+                    $2_version=`($dir/$2-config --version) 2>/dev/null`
+                    if test ".$$2_version" != .; then
+                        CPPFLAGS="$CPPFLAGS `$dir/$2-config --cflags`"
+                        CFLAGS="$CFLAGS `$dir/$2-config --cflags`"
+                        LDFLAGS="$LDFLAGS `$dir/$2-config --ldflags`"
+                        found=1
+                        break
+                    fi
+                fi
+            done
+            #   via standard paths
+            if test ".$found" = .0; then
+                for dir in $with_$2/include/$2 $with_$2/include $with_$2; do
+                    if test -f "$dir/$4"; then
+                        CPPFLAGS="$CPPFLAGS -I$dir"
+                        CFLAGS="$CFLAGS -I$dir"
+                        found=1
+                        break
+                    fi
+                done
+                for dir in $with_$2/lib/$2 $with_$2/lib $with_$2; do
+                    if test -f "$dir/lib$2.a" -o -f "$dir/lib$2.so"; then
+                        LDFLAGS="$LDFLAGS -L$dir"
+                        found=1
+                        break
+                    fi
+                done
+            fi
+            #   in any subarea
+            if test ".$found" = .0; then
+changequote(, )dnl
+                for file in x `find $with_$2 -name "$4" -type f -print`; do
+                    test .$file = .x && continue
+                    dir=`echo $file | sed -e 's;[[^/]]*$;;' -e 's;\(.\)/$;\1;'`
+                    CPPFLAGS="$CPPFLAGS -I$dir"
+                    CFLAGS="$CFLAGS -I$dir"
+                done
+                for file in x `find $with_$2 -name "lib$2.[[aso]]" -type f -print`; do
+                    test .$file = .x && continue
+                    dir=`echo $file | sed -e 's;[[^/]]*$;;' -e 's;\(.\)/$;\1;'`
+                    LDFLAGS="$LDFLAGS -L$dir"
+                done
+changequote([, ])dnl
+            fi
+        fi
+    fi
+    AC_HAVE_HEADERS($4)
+    AC_CHECK_LIB($2, $3)
+    AC_IFALLYES(header:$4 lib:$2_$3, with_$2=yes, with_$2=no)
+    if test ".$with_$2" = .no; then
+        AC_ERROR([Unable to find $1 library])
+    fi
+,
+if test ".$with_$2" = .; then
+    with_$2=no
+fi
+)dnl
+AC_MSG_CHECKING(whether to build against $1 library)
+if test ".$with_$2" = .yes; then
+    ifelse([$5], , :, [$5])
+else
+    ifelse([$6], , :, [$6])
+fi
+AC_MSG_RESULT([$with_$2])
+])dnl
+
Index: ossp-pkg/lmtp2nntp/configure.ac
RCS File: /v/ossp/cvs/ossp-pkg/lmtp2nntp/configure.ac,v
rcsdiff -q -kk '-r1.2' '-r1.3' -u '/v/ossp/cvs/ossp-pkg/lmtp2nntp/configure.ac,v' 2>/dev/null
--- configure.ac	2001/08/20 10:33:22	1.2
+++ configure.ac	2001/08/20 10:45:44	1.3
@@ -15,6 +15,9 @@
 dnl #   feature tests
 AC_SET_MAKE
 AC_PROG_CC
+AC_PROG_CPP
+AC_CHECK_DEBUGGING
+AC_CHECK_EXTLIB([Generic String Library], str, str_parse, str.h, :, echo "REQUIRE STR!"; exit 1)
 
 dnl #   standard output generation
 AC_CONFIG_FILES(Makefile:Makefile.in)