ossp-pkg/xds/configure.ac
1.14
dnl configure.in -- Process this file with autoconf to produce a configure script.
AC_INIT(libxds)
AC_PREREQ(2.52)
AC_REVISION($Revision: 1.14 $)
dnl Get rid of the lousy -g and -O defaults in CFLAGS.
dnl
CFLAGS=${CFLAGS:-}
dnl Checks for paths and programs.
dnl
AC_PROG_CC
AC_PROG_RANLIB
AC_CHECK_PROG(LATEX, latex, latex, :)
AC_CHECK_PROG(POD2MAN, pod2man, pod2man, :)
dnl Set special flags for gcc.
dnl
if test "$GCC" = yes; then
CFLAGS="$CFLAGS -Wall -ansi -pedantic -Wshadow -Wpointer-arith -Wcast-align -Winline -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Wno-long-long"
fi
dnl Check for exact data types.
dnl
AC_CHECK_TYPE(u_int8_t, [xds_uint8_t=u_int8_t],
[AC_CHECK_TYPE(uint8_t, [xds_uint8_t=uint8_t],
[AC_MSG_ERROR([no unsigned 8 bit data type found])])])
AC_CHECK_TYPE(u_int16_t, [xds_uint16_t=u_int16_t],
[AC_CHECK_TYPE(uint16_t, [xds_uint16_t=uint16_t],
[AC_MSG_ERROR([no unsigned 16 bit data type found])])])
AC_CHECK_TYPE(u_int32_t, [xds_uint32_t=u_int32_t],
[AC_CHECK_TYPE(uint32_t, [xds_uint32_t=uint32_t],
[AC_MSG_ERROR([no unsigned 32 bit data type found])])])
AC_CHECK_TYPE(u_int64_t, [xds_uint64_t=u_int64_t],
[AC_CHECK_TYPE(uint64_t, [xds_uint64_t=uint64_t],
[AC_MSG_WARN([no unsigned 64 bit data type found])
xds_uint64_t=undefined])])
dnl
AC_CHECK_TYPE(int8_t, [xds_int8_t=int8_t],
[AC_MSG_ERROR([no signed 8 bit data type found])
])
AC_CHECK_TYPE(int16_t, [xds_int16_t=int16_t],
[AC_MSG_ERROR([no signed 16 bit data type found])
])
AC_CHECK_TYPE(int32_t, [xds_int32_t=int32_t],
[AC_MSG_ERROR([no signed 32 bit data type found])
])
AC_CHECK_TYPE(int64_t, [xds_int64_t=int64_t],
[AC_MSG_WARN([no signed 64 bit data type found])
xds_int64_t=undefined])
dnl
if test "$xds_int64_t" = "undefined" -o "$xds_uint64_t" = "undefined"; then
have_64_bit_support="#undef XDS_HAVE_64_BIT_SUPPORT"
else
have_64_bit_support="#define XDS_HAVE_64_BIT_SUPPORT"
xdr_64_bit_objects="xdr-encode-int64.o xdr-decode-int64.o"
xdr_64_bit_objects="$xdr_64_bit_objects xdr-encode-uint64.o xdr-decode-uint64.o"
xml_64_bit_objects="xml-encode-int64.o xml-decode-int64.o"
xml_64_bit_objects="$xml_64_bit_objects xml-encode-uint64.o xml-decode-uint64.o"
tests_64_bit="xdr-int64.exe xdr-uint64.exe xml-int64.exe xml-uint64.exe"
tests_64_bit="$tests_64_bit xds-mystruct.exe"
fi
AC_SUBST([xds_uint8_t])
AC_SUBST([xds_uint16_t])
AC_SUBST([xds_uint32_t])
AC_SUBST([xds_uint64_t])
AC_SUBST([xds_int8_t])
AC_SUBST([xds_int16_t])
AC_SUBST([xds_int32_t])
AC_SUBST([xds_int64_t])
AC_SUBST([have_64_bit_support])
AC_SUBST([xdr_64_bit_objects])
AC_SUBST([xml_64_bit_objects])
AC_SUBST([tests_64_bit])
dnl Find the library containing the xdr_xxx() functions.
dnl
AC_CHECK_LIB(nsl, xdrmem_create, [xdr_lib=-lnsl])
AC_SUBST([xdr_lib])
dnl Write results.
dnl
AC_CONFIG_FILES(xds.h Makefile regression-tests/Makefile docs/Makefile)
AC_CONFIG_COMMANDS([default], [chmod -w xds.h Makefile regression-tests/Makefile docs/Makefile])
AC_OUTPUT
