ossp-pkg/sfio/configure.in
1.10
dnl ##
dnl ## Autoconf specification for Sfio library
dnl ##
AC_PREREQ(2.13)dnl
AC_REVISION($Revision: 1.10 $)
SHTOOL="./etc/shtool"
AC_SUBST(SHTOOL)
T_MD=`$SHTOOL echo -n -e %B 2>/dev/null`
T_ME=`$SHTOOL echo -n -e %b 2>/dev/null`
SFIO_VERSION=`grep SFIO_VERSION sfio/sfio.h | head -1 | sed -e 's/.*SFIO_VERSION[[ ]]*//' -e 's/L[[ ]]*//'`
PACKAGE_VER=`grep PACKAGE_VER Makefile.in | head -1 | sed -e 's/.*PACKAGE_VER[[ ]]=[[ ]]*//'`
AC_SUBST(SFIO_VERSION)
AC_SUBST(PACKAGE_VER)
echo "Configuring ${T_MD}OSSP Sfio 1999${T_ME} (Safe/Fast IO Library), Version ${T_MD}${PACKAGE_VER}${T_ME}"
echo "Copyright (c) 1991-1999 David Korn, Kiem-Phong Vo and Glenn Fowler"
echo "Copyright (c) 1991-1999 AT&T Labs Research, All rights reserved"
echo "Copyright (c) 1999 The OSSP Project <ossp@ossp.org>"
echo ""
AC_INIT(README)
AC_CONFIG_AUX_DIR(etc)
AC_PREFIX_DEFAULT(/usr/local)
AC_PROG_CC
AC_PROG_CPP
dnl AC_PROG_RANLIB
AC_PROG_LIBTOOL
AC_SET_MAKE
LIBS="-lsfio"
AC_ARG_WITH(stdio-src,dnl
[ --with-stdio-src build with Stdio source emulation (default: no)],
STDIO_SRC="$withval",
STDIO_SRC=no
)dnl
AC_ARG_WITH(stdio-bin,dnl
[ --with-stdio-bin build with Stdio binary emulation (default: no)],
STDIO_BIN="$withval",
STDIO_BIN=no
)dnl
LIBSTDIO_LA=""
O_STDIO_S=""
D_STDIO_S=""
D_STDIO_B=""
if test ".$STDIO_BIN" = .yes; then
D_STDIO_B='stdio_b'
LIBS="$LIBS -lstdio"
LIBSTDIO_LA="libstdio.la"
fi
if test ".$STDIO_SRC" = .yes; then
O_STDIO_S='$(STDIO_S)'
D_STDIO_S='stdio_s'
fi
AC_SUBST(STDIO_SRC)
AC_SUBST(STDIO_BIN)
AC_SUBST(LIBSTDIO_LA)
AC_SUBST(O_STDIO_S)
AC_SUBST(D_STDIO_S)
AC_SUBST(D_STDIO_B)
dnl # Now run Sfio's original IFFE stuff in the background
(cd sfio_c && make CC="$CC" CFLAGS="$CFLAGS")
AC_OUTPUT(dnl
Makefile dnl
sfio-config dnl
sfio/Makefile dnl
sfio_dc/Makefile dnl
sfio_f/Makefile dnl
sfio_t/Makefile dnl
stdio_b/Makefile dnl
stdio_s/Makefile dnl
,dnl
chmod a+x sfio-config
)dnl
