ossp-pkg/l2/configure.ac
1.16
dnl ##
dnl ## L2 - OSSP Logging Library
dnl ## Copyright (c) 2001 The OSSP Project (http://www.ossp.org/)
dnl ## Copyright (c) 2001 Cable & Wireless Deutschland (http://www.cw.com/de/)
dnl ##
dnl ## This file is part of OSSP L2, a flexible logging library which
dnl ## can be found at http://www.ossp.org/pkg/l2/.
dnl ##
dnl ## Permission to use, copy, modify, and distribute this software for
dnl ## any purpose with or without fee is hereby granted, provided that
dnl ## the above copyright notice and this permission notice appear in all
dnl ## copies.
dnl ##
dnl ## THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESSED OR IMPLIED
dnl ## WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
dnl ## MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
dnl ## IN NO EVENT SHALL THE AUTHORS AND COPYRIGHT HOLDERS AND THEIR
dnl ## CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
dnl ## SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
dnl ## LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
dnl ## USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
dnl ## ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
dnl ## OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
dnl ## OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
dnl ## SUCH DAMAGE.
dnl ##
dnl ## configure.in: Autoconf specification
dnl ##
AC_PREREQ(2.52)dnl
AC_REVISION(1.0)
AC_INIT(README)
AC_HEADLINE(dnl
L2, Logging Library, dnl
L2_VERSION, l2_version.c, dnl
[Copyright (c) 2001 The OSSP Project (http://www.ossp.org/)
Copyright (c) 2001 Cable & Wireless Deutschland (http://www.cw.com/de/)])
AC_CONFIG_HEADER(l2_config.h)
AC_PREFIX_DEFAULT(/usr/local)
AC_PLATFORM(PLATFORM)
AC_SET_MAKE
AC_PROG_CC
AC_PROG_CPP
AC_CHECK_DEBUGGING
AC_CHECK_MAINTAINER
AC_CONFIGURE_LIBTOOL
dnl # check for developer tools:
dnl # GNU Bison and GNU Flex
if test ".$enable_maintainer" = .yes; then
AC_PATH_PROG(BISON, bison, NA)
if test ".$BISON" = .NA; then
AC_ERROR([require GNU Bison])
fi
AC_PATH_PROG(FLEX, flex, NA)
if test ".$FLEX" = .NA; then
AC_ERROR([require GNU Flex])
fi
flex_version=`(flex --version 2>/dev/null | awk '{ print $3; }')`
case "$flex_version" in
2.[[5-6]].[[6-9]] ) ;;
* ) AC_ERROR([found GNU Flex version $flex_version; require version >= 2.5.6 (DEVELOPER VERSION!)]) ;;
esac
else
AC_PATH_PROG(BISON, bison, true)
AC_PATH_PROG(FLEX, flex, true)
fi
AC_CHECK_LIB(nsl, gethostname)
if test ".`echo $LIBS | grep nsl`" = . ;then
AC_CHECK_LIB(nsl, gethostbyname)
fi
AC_CHECK_LIB(socket, accept)
AC_CHECK_HEADERS(sys/time.h)
AC_CHECK_FUNCS(inet_aton inet_pton inet_ntoa inet_ntop snprintf vsnprintf setitimer)
sinclude(l2_ut_sa.ac)
SA_CHECK_ALL
AC_CHECK_EXTLIB([Dmalloc], dmalloc, dmalloc_debug, dmalloc.h, AC_DEFINE(WITH_DMALLOC))
AC_OUTPUT(dnl
Makefile dnl
l2.h dnl
l2-config dnl
,dnl
chmod a+x l2-config
)dnl