ossp-pkg/cfg/cfg_syn_scan.l
1.1
%{
/*
** OSSP cfg - Configuration Parsing
** Copyright (c) 1999-2002 Ralf S. Engelschall <rse@engelschall.com>
** Copyright (c) 1999-2002 The OSSP Project (http://www.ossp.org/)
** Copyright (c) 2001-2002 Cable & Wireless Deutschland (http://www.cw.com/de/)
**
** This file is part of OSSP cfg, a configuration parsing
** library which can be found at http://www.ossp.org/pkg/lib/cfg/.
**
** Permission to use, copy, modify, and distribute this software for
** any purpose with or without fee is hereby granted, provided that
** the above copyright notice and this permission notice appear in all
** copies.
**
** THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESSED OR IMPLIED
** WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
** MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
** IN NO EVENT SHALL THE AUTHORS AND COPYRIGHT HOLDERS AND THEIR
** CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
** USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
** ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
** OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
** OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
** SUCH DAMAGE.
**
** cfg_syn_scan.l: regular grammar specification for GNU Flex
**
** ATTENTION: This requires GNU Flex 2.5.6 or newer!
*/
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include "cfg.h"
#include "cfg_syn.h"
#include "cfg_syn_parse.h"
/* how to find our own context */
#define CTX ((cfg_syn_ctx_t *)yyget_extra(yy_globals))
/* provide own input handling */
#define YY_NO_UNPUT 1
#undef YY_INPUT
#define YY_INPUT(buf,result,max_size) (result = yyinput(CTX, buf, max_size))
static int yyinput(cfg_syn_ctx_t *ctx, char *buf, int max_size);
/* location tracking */
#define YY_USER_INIT \
yylloc->first = 0; \
yylloc->last = 0;
#define YY_USER_ACTION \
yylloc->first = yylloc->last; \
yylloc->last += yyleng;
#define YY_USER_ACTION_ROLLBACK \
yylloc->last = yylloc->first
%}
/* scanner options */
%pointer
%option stack
%option reentrant-bison
%option never-interactive
%option noyywrap
/* scanner states */
%x SS_DQ
%x SS_SQ
%x SS_CO_C
%%
/* local variables */
char caStr[1024];
char *cpStr = NULL;
/* whitespaces */
[ \t\n]+ {
/* no-op */
}
/* C-style block comment */
"/*" {
BEGIN(SS_CO_C);
}
<SS_CO_C>"*/" {
BEGIN(INITIAL);
}
<SS_CO_C>(.|\n) {
/* no-op */
}
/* C++-style EOL comment */
"//"[^\n]* {
/* no-op */
}
/* Shell-style EOL comment */
"#"[^\n]* {
/* no-op */
}
/* double-quoted word ("...") */
\" {
cpStr = caStr;
BEGIN(SS_DQ);
}
<SS_DQ>\" {
*cpStr = '\0';
yylval->cpString = strdup(caStr);
BEGIN(INITIAL);
return T_STRING;
}
<SS_DQ>\\[0-7]{1,3} {
unsigned int result;
(void)sscanf(yytext+1, "%o", &result);
if (result > 0xff) {
cfg_syn_error(CTX, CFG_ERR_SYN, yylloc, "escape sequence out of bound");
return 0;
}
*cpStr++ = result;
}
<SS_DQ>\\x[0-9a-fA-F]{2} {
unsigned int result;
(void)sscanf(yytext+1, "%x", &result);
if (result > 0xff) {
cfg_syn_error(CTX, CFG_ERR_SYN, yylloc, "escape sequence out of bound");
return 0;
}
*cpStr++ = result;
}
<SS_DQ>\\n { *cpStr++ = '\n'; }
<SS_DQ>\\r { *cpStr++ = '\r'; }
<SS_DQ>\\t { *cpStr++ = '\t'; }
<SS_DQ>\\b { *cpStr++ = '\b'; }
<SS_DQ>\\f { *cpStr++ = '\f'; }
<SS_DQ>\\(.|\n) {
*cpStr++ = yytext[1];
}
<SS_DQ>[^\\\"]+ {
char *cp = yytext;
while (*cp != '\0')
*cpStr++ = *cp++;
}
<SS_DQ>(.|\n) {
*cpStr++ = yytext[1];
}
/* single-quoted word ('...') */
\' {
cpStr = caStr;
BEGIN(SS_SQ);
}
<SS_SQ>\' {
*cpStr = '\0';
yylval->cpString = strdup(caStr);
BEGIN(INITIAL);
return T_STRING;
}
<SS_SQ>\\(.|\n) {
*cpStr++ = yytext[1];
}
<SS_SQ>[^\\\']+ {
char *cp = yytext;
while (*cp != '\0')
*cpStr++ = *cp++;
}
<SS_SQ>(.|\n) {
*cpStr++ = yytext[1];
}
/* plain text word */
[^ \t\n;{}"']+ {
yylval->cpString = strdup(yytext);
return T_STRING;
}
/* special tokens */
";" { return T_SEP; }
"{" { return T_OPEN; }
"}" { return T_CLOSE; }
/* anything else is returned as is... */
.|\n {
return yytext[0];
}
%%
/* external scanner state transitions */
void cfg_syn_scan_push(cfg_syn_ctx_t *ctx, const char *state);
void cfg_syn_scan_push(cfg_syn_ctx_t *ctx, const char *state)
{
if (strcmp(state, "SS_SQ") == 0)
yy_push_state(SS_SQ, ctx->yyscan);
}
void cfg_syn_scan_pop(cfg_syn_ctx_t *ctx);
void cfg_syn_scan_pop(cfg_syn_ctx_t *ctx)
{
yy_pop_state(ctx->yyscan);
}
/* buffer-based input routine */
static int yyinput(cfg_syn_ctx_t *ctx, char *buf, int max_size)
{
int n;
n = (ctx->inputbuf + ctx->inputlen - ctx->inputptr);
if (n > max_size)
n = max_size;
if (n <= 0)
return YY_NULL;
memcpy(buf, ctx->inputptr, n);
ctx->inputptr += n;
return n;
}